1: /// The two players
 2: type Player = A | B
 3: 
 4: /// The point score in for a player in a game
 5: type PlayerPoints = Zero | Fifteen | Thirty | Forty 
 6: 
 7: /// The score of a game
 8: type Score = 
 9:     | Points of PlayerPoints * PlayerPoints 
10:     | Advantage of Player 
11:     | Deuce 
12:     | Game of Player
13: 
14: /// Compute the next score in a game 
15: let nextPointScore a = 
16:     match a with 
17:     | Zero -> Fifteen
18:     | Fifteen -> Thirty
19:     | Thirty -> Forty
20:     | Forty -> failwith "what??"
21: 
22: /// Check if we've reached deuce
23: let normalize score = 
24:     match score with 
25:     | Points(Forty,Forty) -> Deuce
26:     | _ -> score
27: 
28: /// Score a point in a game
29: let scorePoint score point =
30:     match score, point with 
31:     | Advantage player1, player2 when  player1 = player2 -> Game player1
32:     | Advantage player1, player2 -> Deuce
33:     | Deuce, player -> Advantage player
34:     | Points(Forty, _), A -> Game A
35:     | Points(_, Forty), B -> Game B
36:     | Points(a, b), A -> normalize (Points (nextPointScore a, b))
37:     | Points(a, b), B -> normalize (Points (a, nextPointScore b))
38:     | Game _ , _ -> (* printfn "the game is over!"; *) score
39: 
40: /// Score a whole game, where the game is represented as a sequence of points
41: let scoreGame (points: seq<Player>) = 
42:     Seq.scan scorePoint (Points(Zero,Zero)) points
43: 
44: /// A sample game - A wins every point
45: let game1 = seq { while true do yield A }
46: 
47: /// A sample game - A and B swap points indefinitely
48: let game2 = seq { while true do 
49:                      yield A 
50:                      yield B }
51: 
52: /// A sample game - A and B trade points but A wins more points than B
53: let game3 = seq { while true do 
54:                      yield A 
55:                      yield B 
56:                      yield A }
57: 
58: scoreGame game1 |> Seq.truncate 10 |> Seq.toList
59: 
60: 
61: scoreGame game2 |> Seq.truncate 10 |> Seq.toList
62: 
63: scoreGame game3 |> Seq.truncate 10 |> Seq.toList
64: 
65: 
66: /// Generate a random game
67: let randomGame i = 
68:     let rnd = new System.Random(i) 
69:     seq { while true do if rnd.NextDouble() < 0.5 then yield A else yield B }
70: 
71: // Random testing of 1000 games
72: for i in 1 .. 1000 do 
73:     scoreGame (randomGame i)
74:        |> Seq.nth 10 
75:        |> printfn "result is %A"
76: 
77: